[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

A.1 文法の詳細

 
<式>: 
    `('<式>`)'
    <式> <二項演算子> <式>
    `+' <式>
    `-' <式>
    <左辺値>
    <左辺値> <代入演算子> <式>
    <左辺値> `++'
    <左辺値> `--'
    `++' <左辺値>
    `--' <左辺値>
    `!' <式>
    <式> `?' <式> `:' <式>
    <函数> `(' <式並び> `)'
    <函数> `(' <式並び> `|' <オプション並び> `)'
    <文字列>
    <指数ベクトル>
    <アトム>
    <リスト>
(See section 4.2.10 さまざまな式.)

 
<左辺値>:
    <変数> [`['<式>`]']*

 
<二項演算子>:
    `+' `-' `*' `/' `%' `^'(冪) 
    `==' `!=' `<' `>' `<=' `>=' `&&' `||'

 
<代入演算子>:
    `=' `+=' `-=' `*=' `/=' `%=' `^=' 

 
<式並び>:
    <空>
    <式> [`,' <式>]*

 
<オプション>:
    alphabet で始まる文字列 `=' <式>

 
<オプション並び>:
    <オプション>
    <オプション> [`,' <オプション>]*

 
<リスト>:
    `[' <式並び> `]'

 
<変数>: 
    大文字で始まる文字列 (X,Y,Japan など)
(See section 4.2.2 変数および不定元.)

 
<函数>:
   小文字で始まる文字列 (fctr,gcd など)

 
<アトム>:
   <不定元>
   <数>

 
<不定元>: 
   小文字で始まる文字列 (a,bCD,c1_2 など)
(See section 4.2.2 変数および不定元.)

 
<数>: 
   <有理数>
   <浮動小数>
   <代数的数>
   <複素数>
(See section 3.2 数の型.)

 
<有理数>:
   0, 1, -2, 3/4

 
<浮動小数>:
   0.0, 1.2e10

 
<代数的数>: 
   newalg(x^2+1), alg(0)^2+1
(See section 9. 代数的数に関する演算.)

 
<複素数>:
   1+@i, 2.3*@i

 
<文字列>:
   `"' で囲まれた文字列 

 
<指数ベクトル>:
   `<<' <式並び> `>>'
(See section 8. グレブナ基底の計算.)

 
<文>:
    <式> <終端>
    <複文>
    `break' <終端>
    `continue' <終端>
    `return' <終端>
    `return' <式> <終端>
    `if' `(' <式並び> `)' <文>
    `if' `(' <式並び> `)' <文> `else' <文>
    `for' `(' <式並び> `;' <式並び> `;' <式並び> `)' <文>
    `do' <文> `while' `(' <式並び> `)' <終端> 
    `while' `(' <式並び> `)' <文>
    `def' <函数> `(' <式並び> `)' `{' <変数宣言> <文並び> `}'
    `end(quit)' <終端> 
(See section 4.2.5 文.)

 
<終端>:
    `;' `$'

 
<変数宣言>:
    [`extern' <変数> [`,' <変数>]* <終端>]*

 
<複文>:
    `{' <文並び> `}'

 
<文並び>:
    [<文>]*


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

This document was generated by root on March, 5 2004 using texi2html